#!/usr/local/bin/perl -w
# useperl2mt - Converts use Perl; journal to MT exported data

use strict;
use LWP::Simple;

# Config variables
our $Uid           = 1653;   # use Perl's UID
our $Author        = "miyagawa";
our $AllowComments = 1;
our $AllowPings    = 1;
our $Category      = "Perl"; # category for TypePad

my $url  = "http://use.perl.org/journal.pl?op=list&uid=$Uid";
my $html = get($url);

my $pat = <<'PAT';
<A HREF="(//use\.perl\.org/.*?/journal/\d+)"><B>(.*?)</B></A></TD>
\s*<TD VALIGN="TOP"><EM>(.*?)</EM></TD>
PAT
    ;

my @links = reverse($html =~ /$pat/g);

while (my($date, $title, $link) = splice(@links, 0, 3)) {
    my $html = get("http:$link");
    print create_export($html, $title, $date);
}

sub create_export {
    my($html, $title, $date) = @_;
    my($body) = $html =~ m!</FONT>\n\n\t*<P>\n\t*(.*?)\n\t*<BR><BR></DIV>\n!s or die "no match: $html";
    my @d = $date =~ /^(\d{4})\.(\d{2})\.(\d{2}) +(\d{1,2}):(\d{2})$/ or die "no match: $date";
    my($ampm, $hour) =  ($d[3] > 12) ? ("PM", $d[3] - 12) : ("AM", $d[3]);
    my $mt_date = "$d[1]/$d[2]/$d[0] $hour:$d[4]:00 $ampm";

    return <<DATA;
AUTHOR: $Author
TITLE: $title
STATUS: Publish
ALLOW COMMENTS: $AllowComments
CONVERT BREAKS: 0
ALLOW PINGS: $AllowPings
PRIMARY CATEGORY: $Category
CATEGORY: $Category

DATE: $mt_date
-----
BODY:
$body
-----
EXTENDED BODY:

-----
EXCERPT:

-----
KEYWORDS:

-----


--------
DATA
    ;
}